Log Okuyucu Hazir Kod

tarafından
52
Log Okuyucu Hazir Kod

mIRC Scriptinizde konuşmalarin loglarini ( kayitlarini ) tutmaya yarayan bir koddur. Kullanimi /logs

alias logs {
  window -aekl21S @Log Verdana 12
  .titlebar @Log Dosyaları ...
  editbox @Log Ekranda arama yapacağınız kelimeyi buraya girin...
  echo 7 @Log $findfile($logdir,*.log,0,aline -l 6 @Log $remove($1-,$logdir)) adet dosya mevcut
  echo 12 @Log Görüntülemek istediğiniz dosyayı seçin.
}
menu @Log {
  lbclick:{
    clear @Log | loadbuf @Log $+($shortfn($logdir),$line(@Log,$1,1))
    window -b @Log
  }
  $iif(!$sline(@Log,0),$style(2)) İşlem
  .Bilgi: {
    aline @Log $str(-,5)
    aline @Log 4Dosya bilgileri...
    aline @Log 2Boyutu     :7 $bytes($file($+($logdir,$$1)).size).suf
    aline @Log 2Dosya Adı  :7 $$1
    aline @Log 2Dosya Yolu :7 $logdir $+ $$1
    aline @Log 2İlk oturum :7 $replace($asctime($file($+($logdir,$$1)).ctime),mon,Pazartesi,tue,Salı,wed,Çarşamba,thu,Perşembe,fri,Cuma,sun,Pazar,jan,Ocak,Feb,Şubat,Mar,Mart,sat,Cumartesi,apr,Nisan,May,Mayıs,Jun,Haziran,Jul,Temmuz,Aug,Ağustos,Sep,Eylül,Oct,Ekim,Nov,Kasım,Dec,Aralık)
    aline @Log 2Son kapanış:7 $replace($asctime($file($+($logdir,$$1)).mtime),mon,Pazartesi,tue,Salı,wed,Çarşamba,thu,Perşembe,fri,Cuma,sun,Pazar,jan,Ocak,Feb,Şubat,Mar,Mart,sat,Cumartesi,apr,Nisan,May,Mayıs,Jun,Haziran,Jul,Temmuz,Aug,Ağustos,Sep,Eylül,Oct,Ekim,Nov,Kasım,Dec,Aralık)
    aline @Log $str(-,5)
  }
  .Listeden Çıkar:dline -l @Log $sline(@Log,1).ln
  .Tamamen Sil:{
    clear @Log
    .remove $+($shortfn($logdir),$$1)
    echo 4 @Log $$1 dosyası silindi.
    dline -l @Log $sline(@Log,1).ln
  }
  .Dosya Arama: {
    var %t = $$?="Aranacak kelimeyi girin"
    if $findfile($logdir,$+(*,%t,*).log,0) {
      clear @Log
      clear -l @Log
      echo 5 @Log $findfile($logdir,$+(*,%t,*).log,0,aline -l 6 @Log $remove($1-,$logdir)) adet dosya mevcut
    }
    else { clear @Log | echo 4 @Log Arama kayıtlarında $qt(%t) bulunamadı... }
  }
  .Tüm Liste:clear @Log | clear -l @Log | echo 7 @Log $findfile($logdir,*.log,0,aline -l 6 @Log $remove($1-,$logdir)) adet dosya mevcut
}
on *:input:@Log:{
  if $left($1,1) == / { return }
  if $fline(@Log,$+(*,$1-,*),0) {
    aline 3 @Log || Arama yapılıyor ||
    var %Jenk = 1, %' = ||
    while %Jenk <= $fline(@Log,$+(*,$1-,*),0) {
      if ($mid($fline(@Log,$+(*,$1-,*),%Jenk).text,1,2) != %') {
        aline -p @Log || $+ $fline(@Log,$+(*,$1-,*),%Jenk).text
      }
      inc %Jenk
    }
    aline 5 @log || Arama sona erdi ||
  }
  else { aline 4 @Log || Arama kaydı bulunamadı || }
}